If VersionLessThan 0.9.3
   Message "This mod must be installed by OBMM version 0.9.3 or later to prevent script errors."
   FatalError
EndIf

AllowRunOnLines 
DontInstallAnyPlugins
DontInstallAnyDataFiles

;--Needs Cosmetics
SetVar needsCosmeticsRes False
SetVar needsDeactivation False

;--Core
CopyPlugin "00 Cobl Core\\Cobl Main.esm" "Cobl Main.esm"
CopyPlugin "00 Cobl Core\\Cobl Main DE.esp" "Cobl Main DE.esp"
CopyPlugin "00 Cobl Core\\Cobl Glue.esp" "Cobl Glue.esp"
CopyPlugin "00 Cobl Core\\Cobl Tweaks.esp" "Cobl Tweaks.esp"
If DataFileExists "DLCShiveringIsles.esp"
	CopyPlugin "00 Cobl Core\\Cobl Si.esp" "Cobl Si.esp"
EndIf

SetVar subPack "00 Cobl Core"
For Each DataFolder source %subPack% False
	GetFileName dest %source%
	CopyDataFolder "%source%" "%dest%" True
EndFor

;--Options
SelectManyWithDescriptions "Optionale Unter-Pakete", \
	"Cobl Races","Fuegt Augen, Haare und verschiedene Unterrassen hinzu.", \
	"Cobl Races Balanced","Modifiziert Rassen und Sternzeichen, so dass keine Rasse oder Sternzeichen einen Vorteil gegenueber den anderen hat.", \
	"Cobl Races TNR","Tamriel NPCs Revamped, aber mit Cobl Rassen Haaren und Augen.", \
	"Salmo the Baker","Fuegt viel Essen zum Verkauf bei Salmos Laden in Skingrad hinzu.", \
	"Silent Equip Misc. Items","Entfernt die 'Ihr koennt dies nicht ausruesten'-Nachricht beim Ausruesten von Misc-Gegenstaenden."

Case Cobl Races
	CopyPlugin "00 Cobl Core\\Cobl Races.esp" "Cobl Races.esp"
	SetVar needsCosmeticsRes True
	Break

Case Cobl Races Balanced
	CopyPlugin "00 Cobl Core\\Cobl Races.esp" "Cobl Races.esp"
	CopyPlugin "01 Balanced Races\\Cobl Races - Balanced.esp" "Cobl Races - Balanced.esp"
	SetVar needsCosmeticsRes True
	Break

Case Cobl Races TNR
	CopyPlugin "01 TNR\\Cobl Races TNR.esp" "Cobl Races TNR.esp"
	If DataFileExists "DLCShiveringIsles.esp"
		CopyPlugin "01 TNR\\Cobl Races TNR SI.esp" "Cobl Races TNR SI.esp"
	EndIf
	SetVar needsCosmeticsRes True
	Break

Case Salmo the Baker
  If DialogYesNo "Nutzt du Open (Better) Cities Skingrad/Full?" "Open Salmo?"
      CopyPlugin "02 Patches\\Salmo the Baker, Cobl.esp" "Salmo the Baker, Cobl.esp"
  Else
      CopyPlugin "01 Salmo the Baker\\Salmo the Baker, Cobl.esp" "Salmo the Baker, Cobl.esp"
  EndIf
	SetVar subPack "01 Salmo the Baker"
	For Each DataFolder source %subPack% False
		GetFileName dest %source%
		CopyDataFolder "%source%" "%dest%" True
	EndFor
	Break

Case Silent Equip Misc. Items
	CopyPlugin "02 Patches\\Cobl Silent Equip Misc.esp" "Cobl Silent Equip Misc.esp"
	Break
	
EndSelect

;--OOO
If DataFileExists "Oscuro's_Oblivion_Overhaul.esm"
	If DialogYesNo "Oscuro's Oblivion Overhaul erkannt. Installiere OOO-Cobl Patch?." "OOO-Cobl"
		CopyPlugin "02 Patches\\OOO 1.32-Cobl.esp" "OOO 1.32-Cobl.esp"
	EndIf
EndIf

;--MMM
If DataFileExists "Mart's Monster Mod.esm"
	If DialogYesNo "Mart's Monster Mod erkannt. Installiere MMM-Cobl Patch?" "MMM-Cobl"
		CopyPlugin "02 Patches\\MMM-Cobl.esp" "MMM-Cobl.esp"
	EndIf
EndIf

;--OI
If DataFileExists "Obl-IM.esp"
	If DialogYesNo "Oblivion Improved erkannt. Installiere OI Patch?" "OI"
		CopyPlugin "02 Patches\\Oblivion Improved - Cobl.esp" "Oblivion Improved - Cobl.esp"
	EndIf
EndIf

;--Wrye Bash
If DataFileExists "Bash Patches\\Rational_Names.csv"
	If DialogYesNo "Einige zusaetzliche Mods koennen installiert werden, die NUR mit dem Bashed Patch funktionieren. Wenn du diese installierst, MUSST du sie manuell deaktivieren und dann in den Bashed Patch mergen, indem du den Anweisungen aus der Readme folgst. Wenn du diese installierst und NICHT desaktivierst, wird das Spiel beim STARTEN CRASHEN! Willst du jetzt nach dieser Warnung die Mods ansehen?" "Wrye Bash Merge-Only Mods"

		SelectManyWithDescriptions "Wrye Bash spezifische Mods", \
			"Cobl Filter Late","Stellt Essen vieler verschiedener Mods fuer Essteller und Buefettteller zur Verfuegung.", \
			"Item Interchange", "Durch das Mergen werden Gegenstaende verschiedener Mods ausgetauscht. Das erhoeht die Interaktion zwischen den Mods stark."
		
		Case Cobl Filter Late
			SetVar needsDeactivation True
			CopyPlugin "00 Cobl Core\\Cobl Filter Late MERGE ONLY.esp" "Cobl Filter Late MERGE ONLY.esp"
			;UncheckESP doesn't work for files from sub-directories.
			;UncheckESP "00 Cobl Core\\Cobl Filter Late MERGE ONLY.esp"
			Break
		
		Case Item Interchange
			SetVar needsDeactivation True
			CopyPlugin "03 Item Interchange\\Item interchange - Extraction.esp" "Item interchange - Extraction.esp"
			If DialogYesNo "Item Interchange: Willst du die FCOM Variante?" "FCOM"
        CopyPlugin "03 Item Interchange\\Item interchange - Placement for FCOM.esp" "Item interchange - Placement for FCOM.esp"
			EndIf
			If DataFileExists "DLCfrostcrag.esp"
        If DialogYesNo "Item Interchange: Nutzt du Frostcrag Revisited?" "Frostcrag Revisited"
          CopyPlugin "03 Item Interchange\\Item interchange - Placement for Frostcrag Spire Revisited.esp" "Item interchange - Placement for Frostcrag Spire Revisited.esp"
        Else
          CopyPlugin "03 Item Interchange\\Item interchange - Placement for Frostcrag Reborn.esp" "Item interchange - Placement for Frostcrag Reborn.esp"
        EndIf
			EndIf
			SelectWithDescriptions "Menge des Essens und der Zutaten bei Verkaeufern", "Zutaten in Massen", "Verkaeufer lagern Essen und Alchemie-Zutaten in groesseren Mengen.", "Zutaten in Massen, reduziert", "Verkaeufer werden mehr Sachen als normal verkaufen, aber bei weitem nicht so viel wie bei der anderen Variante", "Nichts", "Du willst kein erweiteres Haendlerlager"	
        Case Zutaten in Massen
          CopyPlugin "03 Item Interchange\\Item interchange - Option, Ingredients in Bulk.esp" "Item interchange - Option, Ingredients in Bulk.esp"
        Break
        Case Zutaten in Massen, reduziert
          CopyPlugin "03 Item Interchange\\Item interchange - Option, Ingredients in Bulk, reduced.esp" "Item interchange - Option, Ingredients in Bulk, reduced.esp"
        Break
        Case None
        Break
      EndSelect
			CopyPlugin "03 Item Interchange\\Item interchange - Placement.esp" "Item interchange - Placement.esp"
			CopyDataFile "03 Item Interchange\\Item Interchange_readme.rtf" "Docs\\Item interchange_readme.rtf"
			Break

		EndSelect
	EndIf
EndIf

;--Cosmetics Warning
If Equal %needsCosmeticsRes% True
	Message "Du nutzt eine Rassen-basierende Mod, also musst du das Cobl Cosmetic Res Paket installieren!"
EndIf

If Equal %needsDeactivation% True
	Message "Stelle sicher, dass du die Cobl Filter Late und/oder Item Interchange esps desaktivierst und in den Bashed Patch merged."
EndIf

